Title 'Grice & Iwasaki Confidence Interval for Simplified Composite'.

* First: Run Means procedure to obtain group means.
*        Copy and Paste the Means in the 'M' (means) matrix below.
*        You will need to separate the numbers by commas and enter semi-colons at the end of each row.
*        Enter the lowest sample sizes for each group in the 'N' matrix below. 
*        Order is important for all of the matrices. The order here is European Americans (EA), 
*        Asian International (AI), and Asian American (AA) for the groups; N E O A C for the dependent 
*        variables. 

MEANS
  TABLES=n e o a c  BY grp
  /CELLS MEAN COUNT.

* Second: Run the GLM procedure to obtain the SSCP Error matrix for the MANOVA. 
*         Copy and Paste the 'Sums of Squares and Cross Products' matrix from the output to the 'E' 
*         matrix below. You will need to separate the numbers by commas and enter semi-colons at the 
*         end of each row.

GLM
  n e o a c  BY grp
  /METHOD = SSTYPE(3)
  /INTERCEPT = INCLUDE
  /PRINT = RSSCP             /* RSSCP keyword prints the residual matrix */
  /CRITERIA = ALPHA(.05)
  /DESIGN = grp .


* Third: Fill in contrast coefficients in the 'C' matrix below. Again, group order is important 
*        (EA, AI, AA).

* Fourth: Fill in the weights for the multivariate composite in the 'A' matrix below. Again the order
*         of the dependent variables is important (N E A O C).

* Fifth: Input the value for 'gcr' below. This value must be obtained from Harris' gcr tables or program
*        using s, m, and n degrees of freedom and a priori alpha (e.g., .05, .01).

* Sixth: Run the program. The 'ci_low' and 'ci_high' values constitute the confidence interval. 


matrix.
compute C={-1, .5, .5}.
compute A={0, -1, 1, -1, 0}.
compute N={75, 72, 56}.
compute X={
 93.9467,	126.2267,	113.4000,	116.8400,	113.8667;
 97.0694,	108.1944,	111.3611,	106.4167,	108.3750;
 97.0357,	114.9821,	126.9821,	119.6786,	113.3393}.

compute cXa=c * X * T(a).
print cXa.

compute E={
  90650.368,	-19544.030,	-2139.170,	-6905.080,	-31111.087;
 -19544.030,	68087.407,	25963.127,	-5340.435,	24283.356;
 -2139.170,		25963.127,	58283.593,	10117.645,	6850.589;
 -6905.080,		-5340.435,	10117.645,	61033.794,	3838.257;
 -31111.087,	24283.356,	6850.589,	3838.257,	68134.095}.

compute aEa=A * E * T(A).
print aEa.

compute gcr = 0.0706.
compute lamcrit = gcr / (1 - gcr).
compute cjs=(c &* c) * (1 / T(N)).
compute ci_low=cxa - sqrt(cjs * aEa * lamcrit).
compute ci_high=cxa + sqrt(cjs * aEa * lamcrit).
print ci_low.
print ci_high.
end matrix.