Title 'Grice & Iwasaki MANOVA results'.

Subtitle 'Step 1 Analyses'.
* Both univariate and multivariate results will be printed from the MANOVA command below.
MANOVA n e o a c by grp(0,2)
  /print cellinfo(means) homogeneity
  /discrim(raw stan) alpha(1.0)    /* 'alpha(1.0)' insures all discriminant functions will be printed */
  /design.

* The following GLM procedure will yeild the same results but will not print the discriminant function
* coefficients. It reports Roy's g.c.r. as an eigenvalue (lambda) rather than a proportion of overlap (theta).
GLM
  n e o a c  BY grp
  /METHOD = SSTYPE(3)
  /INTERCEPT = INCLUDE
  /PRINT = DESCRIPTIVE ETASQ HOMOGENEITY
  /CRITERIA = ALPHA(.05)
  /DESIGN = grp .


Subtitle 'Step 2 Analyses'.
* Compute the 1st full multivariate composite.
COMPUTE Comp1=(N * -0.0058) + (E * -0.06027) + (O * 0.04239) + (A * -0.02758) + (C * 0.00748).
MANOVA Comp1 BY grp(0,2)
  /design.      /* Using the MANOVA routine to conduct univariate ANOVA on 'Comp1'. */

COMPUTE Comp2=(N * -.007) + (E * -.00017) + (O * -.0423) + (A * -.03102) + (C * -.00956).
MANOVA Comp2 BY grp(0,2)
  /design.      /* Using the MANOVA routine to conduct univariate ANOVA on 'Comp2'. */


Subtitle 'Step 3 Analyses'.
COMPUTE Simp1=(E * -1) + (O * 1) + (A * -1).
VARIABLE LABEL Simp1 'Reserved-Openness'.


Subtitle 'Step 4 Analyses'.
* Test Simp1, the simplified multivariate composite (Reserved-Openness) for statistical significance.
* F-critical (p = .05) for the test is 7.60. 
MANOVA Simp1 BY grp(0,2)
  /print cellinfo(means)
  /design.

Subtitle 'Step 5 Analses'.
* Follow-up Tests comparing three groups on simplified multivariate composite (Reserved-Openness).
ONEWAY Simp1 BY grp
  /contrast = -1 .5 .5  
  /contrast = -1  1  0
  /contrast = -1  0  1
  /contrast =  0 -1  1
  /statistics descriptives
  /plot means
  /missing analysis.

* The annotated syntax for computing a confidence interval for a contrast on a simplified composite is 
* in a separate file. 

Subtitle 'Additional Analyses'.
* Computing structure coefficients; i.e., correlations between multivariate composite and DVs.
CORR Simp1 with N E O A C.